|
» [url=http://bbs.ngacn.cc/read.php?tid=2883682][D区有爱] [文字理论贴]德鲁伊宏制作/可求宏[1.23更新][/url]
[size=120%][color=blue] 游戏Ver 3.1.3 更新Date 12.1.2009 [/color][/size]
[color=green]不看原理.直接需要宏的可以直接看文章后半段
求宏的请附带具体希望实现的功能[/color]
[size=200%] [b] =============目录=============== [/b] [/Size]
[size=120%][color=skyblue][b]目录[/b]
[b]Part.A 宏的作用[/b]
为什么要作宏,宏的功能
宏的泛用性和精确性
个人制作/使用宏的心得
[b]Part.B 如何编制宏[/b]
宏的逻辑分类：单目标多技能类,单技能多目标类
宏的命令分类：循环,抽筋宏,随即,判断
宏的优化办法：制作前提,赋予逻辑,加入小功能
宏变身的对比
宏命令的一些注意事项
宏命令的一些优劣性
[b]Part.C 成品宏[/b]
宏及其功能解释
Part.D 更新部分[/color][/size]
[size=200%] [b] ==============正文=============== [/b] [/Size]
[size=150%][b][color=skyblue]Part.A 宏的作用[/color][/b][/size]
[size=120%][b][color=skyblue]为什么要作宏？[/color][/b][/size]
WOW里面几乎每一个职业的所有技能都有用，而其技能目标又受制于一些使用条件,主要碰到的问题就是[color=red]目标的选定[/color]和[color=red]相应的技能释放[/color]。我们一方面希望充分有效的利用各个技能，一方面希望操作能有所简化。对于这两个[i]几乎矛盾[/i]的方面,我们只能通过宏来实现这点。
[size=120%][b][color=skyblue]宏的功能：[/color][/b][/size]
上面所说做宏的目的也就很明确的决定了宏的功能：[color=red]简化操作,优化操作,提高操作空间[/color]
[size=120%][color=skyblue] ----------------做什么样子的宏---------------- [/color][/size]
[color=teal]个人认为宏的作用在于：
1. 精确有效快捷的使用正确的技能,
宏反应的正确性
2. 可以对于简单甚至复杂情况做出判断,
宏反应的智能性
3. 减少操作难度上的需要和减少技能数量所需按键的数量，
宏操作的便利性
4. 实现简单实现复杂高难度动作
宏操作的强大性
5. 在不把局面可能搞得更糟情况下,简化概括局面
宏使用不能违背初衷
6. 尽可能把界面美化和技能CD情况观察方便
宏界面的美观和实用[/color]
[color=silver]关于以上做出略为解释
1. 使用技能时，尽可能有效释放正确技能,而不是返回错误信息：例如：你需要一个目标，你不能攻击该目标等。当然也需要用对技能，谁也不希望在只需要用一个消失的情况，宏多用了或错用了一个暗影斗蓬。
2. 用宏来实现1键冲锋焦点目标,这种不用插件和宏情况下比较消耗手速和精力的操作，这是我们希望看到的。这里并不是将切焦点目标并用一个技能说的很难，只是这类操作需要迅速准确的施放,经常连续此类操作有可能造成手部疲劳或者错误
3. 关于用来实现自然迅捷-〉治疗之触之类的宏，实际上技能栏上还是需要有自然迅捷这个技能的,因为自然迅捷不一定用治疗之触，有可能用催眠，愤怒，旋风等。有想法的人事不推荐使用类似的宏，还是靠手速比较好，或者主键位留着自然迅捷这个技能，将宏放到副键位上关键的时候也可以用到。
4. 关于将重欧和裂伤或者其他熊捆绑的宏，我个人认为有些不恰当，一方面来说重殴又可能打到另外一个目标比较说需要羊或者控制的目标，另一方面来说怒气不一定支持使用主攻技能下全程使用重殴例如当2T的时候。[/color]
[size=120%][b][color=skyblue]宏的泛用性和精确性[/color][/b][/size]
宏自身的[color=red]泛用性和精确性[/color]几乎是两个对立的要求,好比一键狗熊tank宏虽然泛用性好，手工操作简单，但是个别情况时候有点乏力。如果采用一个宏只控制一个技能,那么精确度确实上去了，但是同时需要更多手工操作来使用其他宏，也就是说泛用性下降。我个人认为制宏的首要目标是保持高精准度，在此条件下追去泛用性和简单操作。如果想偷懒的同学可以,减少一定精确性来追求泛用性。而在我看来泛用性和精确性,本来就需要靠自己找到一个[color=red]适合的均衡点。[/color]
[size=120%][b][color=skyblue]个人关于宏的一些心得：[/color][/b][/size]
[color=teal]循环类宏应该给个键位,但绝对不是主键位,也不应该需要对应零散技能.有个键位能在一键T/D/H时候就用到就了,能够mouseclick或者硬币卡住就可以，不要太依赖循环类完全是为了偷懒用的。
两种大体上的宏编制的方向，单目标多技能类，单技能多目标类下面会解释。
单目标多技能类绝对是减少技能同时减少所按键的最佳方法，当然其每个技能的应用空间也就受到了一定制约，大大提升宏的泛用性,当然同时强调了选择目标的精确性。
单技能多目标类为使用者提供了关于此技能更多的应用空间这点是毋庸置疑的，其在按键数量上并没有质上的削减导致所需要的按键和按键组合以就是相当多的，所以这类编制并非所有玩家都使用
ALT不是唯一个组合特殊键,shift和ctrl也可以用。通常按习惯来说alt比较适合对自己或者对焦点施法用,ctrl可以组合一些吃东西，叫卖，等等不是战斗中特别急需使用的技能。Shift+XX实际上可以提供不少按键组合，而且也很方便按到
[option]类,和一些技能的优化使用在宏的编制上其实是重中之重，细微上的小优化和判断让战斗操作性更加可行，舒服及实用[/color]
[color=indigo]宏的制作和使用,一定程度是跟操作者[/color][color=red]操作习惯,选目标习惯[/color] [color=indigo]而定的.
我的宏基本是按照单技能多目标宏为蓝本衍生出来的,即减少使用技能时,系统报错诸如你需要一个目标,目标不能为友方之类。按宏一定会反应出宏所对应的出技能,但目标不一定为当前目标。当然也根据自己习惯编制单目标多技能宏.上
此外因为宏都按我自己的习惯编制的,且目标选的是什么我心里也基本有数，所以按宏时候大概会产生什么动作也能预见。因为目标性质上可能会导致宏错误使用时,我一般会下意识点自己,选择个敌人或者点地板取消目标,来弥补宏设计上的不足。我个人按技能控制的键盘数量和组合键位比较多,按键基本不出错,也没有按键风怒的习惯,所以宏的编制上加入了一些可能有负面影响的东西。有不好按键习惯的人,制宏应该考虑相关要素[/color]
[color=darkred]强烈提示：文中所有宏中涉及含有”；”部分,之后均有一个“空格”,若没有“空格”,宏将无法正常运转. 由于排版和文字显示问题“空格”容易遗漏，请见谅。[/color]
[size=150%][b][color=skyblue]Part.B 如何编制宏[/color][/b][/size]
[size=120%][b][color=skyblue]宏的逻辑分类：单目标多技能类,单技能多目标类[/color][/b][/size]
[color=skyblue]什么是单目标多技能类,单技能多目标类宏：
单目标多技能宏[/color]
[color=teal]优点：目标选择准确,不会将技能错误放其它目标上，在保持目标准确的前提下，选择最合适的技能对其使用。很简单有效减少所需控制的技能数量。[/color]
[quote]#showtooltip
/cast [target=target,nostance,nohelp] 月火术;
[target=target,nostance, help] 回春 [/quote]
在人性下,通过敌我的判断，从而使用不同技能
(注：没有插件的情况下,潜行不切技能条...
某个插件的某个功能,不清楚..所以别问我是那个插件)
[quote]#showtooltip
/cast [stance:3,stealth] 突袭;
[stance:3,nostealth] 斜掠[/quote]
在豹子形态下,通过潜行状态与否释放不同技能
可将以上2个宏整合并且不断加入新功能(没什么使用性)
[quote]#showtooltip
/cast [target=target,nostance,nohelp] 月火术;
[target=target,nostance, help] 回春;
[stance:3,stealth] 突袭;
[stance:3,nostealth] 斜掠;
[stance:1,harm] 低吼;
……etc[/quote]
以此可见单目标多技能类宏可以瞬间将大量技能的释放通过一个宏来进行操作.
[color=skyblue]单技能多目标宏[/color]
[color=teal]优点：技能释放准确，不会出现使用其它技能的情况, 有效的第一时间使用技能,并按宏规定级别选择最有效的目标,能提供很高的操作空间[/color]
[color=blue]此类宏又根据技能本身的属性分为对友对敌类[/color]
[color=skyblue]治疗和buff类技能[/color]
[quote]#showtooltip
/cast [target=target,help,nochanneling,nodead] 愈合;
[target=targettarget,help,nochanneling,nodead] 愈合;
[target=player,nochanneling] 愈合[/quote]
此宏实际上融合了治疗协助宏,目标优先级别最高，其次目标的目标，最后是自己。如果不习惯者可将第二行去掉，即去掉协助功能。当然此宏也可以扩充，第一行之前加上[mod:alt,target=player] 愈合—治疗自己；[mod:alt,target=focus,exists] 愈合—治疗焦点；[target=mouseover,exists,help,nodead] 愈合—〉治疗鼠标位置。加alt相当于多用了一个组合键位，alt自身施法控和组合键位有多余的同学可以尝试，追加了一个alt实际上提升宏的准确行，但是也增加操作的复杂度。如果是追加mouse位置,那么目标选取的精度就下降了，转为强调鼠标位置的放置。
[quote]#showtooltip
/cast [target=target,help ,nodead] 荆棘术;
[target=player] 荆棘术[/quote]
将爪子荆棘术激活这类也可以作类似的宏处理，宏中去掉targer=targettarget，当然也可以加上一定的密语和喊话，这样子的好处，就是用起来会很舒服目标空白或者为敌人的时候点宏，不用使用alt便可以对自身施法,当然也不用加入切目标的动作，使用起来比较舒服.
[color=skyblue]攻击和对敌类技能[/color]
相关于此类的宏我觉得首要的是 冲锋或者缠绕,吹风焦点目标
[quote]#showtooltip
/cast [mod:alt,target=focus,exists] 野性冲锋；
[target=target,nohelp,exists,nodead] 野性冲锋[/quote]
尤其是在3.22猫形态5星可以使下个低于10秒的法术顺发,使得控制/打断焦点目标的机会和价值都大幅提升了.
另一类是第一时间嘲讽/攻击/控制群拉中跑掉的怪物,而目标仍放在原目标上.也就是经常群拉boss和其小弟,某小弟不小心遗漏这类情况.
[quote]/cast [target=mouseover,exists,nohelp,nodead] 嘲讽;
[target=target,nohelp,nodead] 嘲讽[/quote]
[color=skyblue] [size=120%]宏的命令分类：循环,随即,判断[/size][/color]
[color=skyblue]循环宏[/color]
castsequence就是按照一定的顺序轮流释放法术
格式如下
[quote]/castsequence [options] reset=#/target/combat spell1, spell2, spell3 ....[/quote]
[options] 里的命令是判定在什么条件下该动作生效，可选填。
reset=#/target/combat这是这个宏的重置条件，可以为时间(#)(这里的时间指的是你多少秒不使用此宏的时间,从最近一次点宏开始计算)，可以为切换目标(target)，也可以是是否在战斗状态(combat)，也可以多个条件同时使用,也可以选填
另外需要注意的是spell1,无论因为魔法不够的原因,还是技能CD还没有冷却,一切可能导致spell1没有使用出去的原因,顺序不会跳到spell2,只有spell1用过以后，顺序才会向后。
循环的代表就是[color=red]一键Tank宏[/color]
[quote]#showtooltip
/startattack
/castsequence reset=1.5/combat 裂伤(熊),割伤,横扫(熊),裂伤(熊),横扫(熊),横扫(熊),裂伤(熊),横扫(熊),横扫(熊)
/cast 重殴[/quote]
此宏需要 强化裂伤和足够的命中,当然也可以按下面自行编制适合自己的tank宏
裂伤(熊),割伤,横扫(熊) 对换为A B C
A技能 仇恨大 但是有CD 因天赋不同4.5-6CD,本着好了就用的原则
B技能 DOT 叠5次 15秒周期伤害, 但狗熊命中不一定够,所以15秒补一个不一定能补上
C技能 在A技能CD B技能5层后 纯补空儿技能
BOSS战刚开始肯定是先手动 精灵火*1 开狂暴虎一轮 补好5个B跑好位置 开始进入宏循环状态 如果战斗中间 需要开生存类技能 那么宏制作时也要考虑好相应对策
狗熊GCD先考虑为1.5秒
如果A为4.5秒 说明每2个A中间能放2个其他技能 15秒/4.5秒3<结果<4 取4的话还是存在B未命中补一个问题 那么 就 A B C A C C A B C
如果A为>=4.5秒 说明每2个A中间能放3个其他技能 15秒/6秒 2<结果<3 取 那么就是
A B C C A B C C
如果命中够且ACD为4.5秒循环就改为A B C A C C A C C
#showtooltip
/startattack
/castsequence reset=1.5/combat x,x,x,x,x,x,x,x,x
/cast 重殴
X部分换成ABC在代入中文
[quote]/castsequence reset=target 野性印记,荆棘术[/quote]
按第一下放用 野性印记,第二次用 荆棘术,切目标将重制顺序,加buff挺好用的
[quote]/castsequence reset=30 树皮术,生存本能[/quote]
第一次使用时，用树皮术，第二次用生存本能，当时间为30秒时，即树皮术CD，重制顺序
[color=skyblue]抽筋宏[/color]
[quote]/castsequebce / /usesequence reser=? (空格),A
/cast / /use B [/quote]
第一个语句第一边点击的时候 被空格 空循环了
即第一次使用 B 技能/物品
第二次点,第一个语句转为运行 A
因为A成功运行产生GCD的时候,B此时无法使用
A,B可以为同为物品或法术,或完全不同,注意调整/use /cast 以匹配就可以了
关于reset=? 如果reset=0.1或者0.01(秒)即极短时间顺序就被重置了
连击速度不够快,此宏永远反应为B
如果reset=99或更多, 将会出现上场战斗时,点击的顺序没有重置
此宏直接先使用A
所以综上,抽筋宏中 reset=time 需要调试至适合手速,
既要保证快速连击时,顺序不会重置,可以正常使用A，
也要足够长的不点击时,顺序可以重置达到使用B的目的
[color=skyblue]随即技能宏[/color]
/castrandom就是随机施法
[quote]/castrandom [option] spell1, spell2....[/quote]
[option]为释放宏的条件，和上边讲的一样,也可选
后边接的法术，也可以是物品，使用这个宏的时候会随机挑选出一个法术或者物品使用一般用于法师的变羊，变猪，变乌龟等... 或者各种坐骑随机使用
比如说：
/castrandom [harm] 变猫,变狗,变猪……
[color=skyblue] [options] 判断条件[/color]
可以使用的部分条件：
[help] / [nogelp]目标为友好/不友好
[target=mouseover,help,exists] 鼠标停留在友好目标上
[target=targettarget, help, exists] 目标的目标是友好的
[target=player] 目标为玩家
[target=targettarget] 目标为目标的目标
[modifier:alt]/[mod:alt] 按住alt键
[nomod:alt] 不按住alt键
[mod] 按住shift,alt,ctrl任意键
[nodead] / [dead]目标非死亡/未死亡
[harm] / [noharm]可以攻击的目标/不可攻击的目标
[indoor] 室内 / [outdoor] 室外
[swimming] 游泳状态
[flyable] 可飞行
[combat]/[nocombat] 战斗/非战斗
[nostance] 人形
[stance:1] 熊形态 2海豹 3猎豹 4旅行 5飞行
[nostace:1] 不是熊形态
[nogroup] 不在一个团队
[b][size=120%][color=skyblue]宏的优化办法：制作前提,赋予逻辑,加入小功能[/color][/size][/b]
[color=skyblue]制作前提[/color]
[quote]#show tooltip
/cast [nostance:1] 巨熊形态
/cast [stance:1] 低吼[/quote]
比如说你可能是个专业T,那么低吼一定在你快键上,当你人型点低吼，系统会提示你需要某个形态或者潜行怒气什么的。说白就是你想用低吼必须先变狗熊,想伏击必须潜行一个道理,有些技能的释放需要一些前提,那么宏中就加入，所需要的前提，让技能能够正常使用。
[color=skyblue]赋予逻辑[/color]
相同的命令，但是不同的顺序,就会有不同的逻辑
跟自己操作习惯使用,选择不同逻辑顺序,举例如下
[quote]#showtooltip 自然迅捷
/stopcasting
/cast [target=target,help,nodead] 治疗之触;
[target=player] 治疗之触
/stopcasting
/cast 自然迅捷[/quote]
(请于走路状态使用,否则易悲剧)点宏第一次打断当前施法并实用自然迅捷
猛击宏第二次实用治疗之触
[quote]#showtooltip 自然迅捷
/stopcasting
/cast 自然迅捷
/cast [target=target,help,nodead] 治疗之触;
[target=player] 治疗之触
/stopcasting[/quote]
点宏第一次直接实现瞬加效果
这2个宏理论上OK,未测试。(从小到大一直野性…没出过那个自然迅捷)
[color=skyblue]加入小功能[/color]
比如攻击的时候.加入/startattack
[quote]/startattack
/cast 裂伤[/quote]
因为一般来开始普通攻击是不会放在技能条上的,但是没有怒气打一个技能的话,永远不用开始普通攻击
另外比较实用的是人形技能前加入更换法伤武器
动物形态技能前加入更换野性武器
要知道400法术效果,可是白来的
此外用激活的时候喊个话什么的
[b][color=skyblue]喊话宏[/color][/b]
[quote]/Script local i=Random(1,3);s={"语句一","语句二","语句三"};
/Script SendChatMessage(s[i],"yell");[/quote]
随即喊话的宏
如果喊话融合在其他技能中可以通过加入stopmcro命令还ban某些情况,从来进行正常喊话
[quote]/stopmacro [combat][target=none][target,nodead]
/y rise my solider, rise and fight one more[/quote]
[b][color=skyblue]变身命令的对比[/color][/b]
[quote]常规技能(面板技能，非宏)[/quote]
点一下是一下,只能人->熊 熊->人 不能直接熊-〉熊
熊->熊需要手速,自行处理
晕眩状态下,点击会变人形
[quote]/cancelform
/cast 巨熊形态(变形)[/quote]
因为第一个命令并没有GCD的特点,变身反应最快
可以人-〉熊 熊-〉熊 熊-〉人(GCD中点击)
晕眩状态下,点击会变人形
[quote]/cast !巨熊形态(变形)
===
/cast [stance:1]巨熊形态(变形);巨熊形态(变形)
此两宏理论上为等效。[/quote]
在GCD的CD情况下的有效点击才会进行变身.
(咬冰法被冰寒刺骨,产生GCD)
即点击可能不是第一时间,解除限制移动
任何情况只能人-〉熊,熊-〉熊,任何操作不会出现人形
晕眩状态下,点击无反应
最理想的变身宏：
1.晕眩状态下,点击无反应
2.变身反应快,不受或少受GCD制约
3.可以根据点击速度或者其他 人-〉熊,熊-〉熊，熊-〉人
[color=red]结论:[/color]
/cancelform
/cast 巨熊形态(变形)
相比较于：常态技能,变身反应快,具有一定熊,人互相切换能力
具有可以完全替代常态技能的功能
且可以充当一定程度的解除限制功能,是较为优秀的变身宏
/cast !巨熊形态(变形)
有着稳定这个不可比拟的优点
但其只能单向变身,任何使用不能变人
只能作为是一个非常优秀的解除限制技能
如果你不需要熊变人的功能这也将是一个不错的变身宏
推荐整合宏
[quote]/usesequence reset=0.5 ,联盟徽章
/cast [stance:1]!巨熊形态(变形);[stance:2]!水栖形态(变形);[nostance][stance:3]!猎豹形态(变形);[stance:4]!旅行形态(变形);[stance:5]!飞行形态(变形)[/quote]
与徽章整合,第一次点击可以,本形态解除限制移动
第二次点击 使用徽章
[size=120%][color=skyblue]宏命令的一些说明[/color][/size]
[color=teal]#showtooltip
宏的说明字和图标以宏中的使用技能的说明文字和图表作为显示
#showtooltip
/cancelform
/cast [outdoors,nocombat,flyable] 迅捷飞行形态;
[swimming] 水栖形态;
[outdoors] 旅行形态
水里显示水栖形态的技能图标，其它情况类似,技能会随宏最后使用的技能变动而变动
#showtooltip 自然迅捷
/cast自然迅捷
/cast 治疗之触
只以 自然迅捷 作为技能图标显示,便于观察CD时间
[/color]
[size=120%][color=skyblue]宏命令的一些优劣分析[/color][/size]
[color=indigo]#showtooltip 能让你和清楚得看到你即将使用的技能,或者你需要观察的技能CD
但在某些情况下，可能会显示红色的问号影响美观
/castsequence 某些必然连续或者必然顺序的不同技能,可以用一个宏来代替
不能跳过顺序或者改变顺序使用某个技能,需要超过顺序使用技能时易悲剧
/castsequence rest=time A，B 可以保证A技能有CD的情况,不会用到B技能
如果2个技能均为CD技能另外一个技能的CD时间不方便观察
[option] 可以对使用技能进行一定程度的控制,
但请将条件写的合适,否则不能使用,例如[target=taget,help] 月火…
/stopcasting 确保当前技能的正常使用
上一个技能，可能会因为误按被意外打断掉
/cancelform 第一时间取消形态，方便在此情况下进行下一个动作
误按会导致公共CD的浪费,或更甚 [/color]
[b][size=150%][color=skyblue]Part.C 成品宏[/color][/size][/b]
[color=green]宏有关技能顺序按照恢复-平衡-野性,技能书中的顺序,宏的用途和功能为野德向
宏制作的蓝本为单技能多目标类，有空将放出单目标多技能类[/color]
[size=120%][color=skyblue]恢复 技能[/color][/size]
回春术 治疗宏
[quote]#showtooltip
/equip 法术武器 <----加入 可不加入
/cast [target=target,help,nochanneling,nodead][target=targettarget,help,nochanneling,nodead][target=player,nochanneling] 回春术[/quote]
如果目标可治疗,则为目标治疗;
如果没有满足上个条件且目标的目标可治疗,则为目标的目标治疗
如果没有满足上述条件,则为自己治疗
不影响常规点选目标释放技能的使用,并且融入协助目标宏,此外某些情况可以直接治疗自己。
复生 与 生命绽放 进行link
宁静 未处理
愈合 治疗宏
[quote]#showtooltip
/cast [target=target,help,nochanneling,nodead][target=targettarget,help,nochanneling,nodead][target=player,nochanneling] 愈合[/quote]
功能参考 回春术
消毒术 与 驱毒术 进行 link
治疗之触 治疗宏-特殊情况可复活
[quote]#showtooltip
/cast [target=target,nocombat,help,dead][target=mouseover,nocombat,help,dead,exists] 起死回生
/cast [target=target,help,nochanneling,nodead][target=targettarget,help,nochanneling,nodead][target=player,nochanneling] 治疗之触[/quote]
在非战斗时,如果目标为死亡/鼠标位置的目标为死亡 对其释放 复活
其他情况雷同 回春术
生命绽放 治疗宏-特殊情况可战复
[quote]#showtooltip
/cast [target=target,help,dead][target=mouseover,help,dead,exists] 复生
/cast [target=target,help,nochanneling,nodead][target=targettarget,help,nochanneling,nodead][target=player,nochanneling] 生命绽放[/quote]
如果目标为死亡/鼠标位置的目标为死亡 对其释放 复生
其他情况雷同 回春术
解除诅咒 优化宏
[quote]#showtooltip
/cast [target=target,help,nodead,exists][target=player] 解除诅咒[/quote]
如果目标存活且为右方, 对其释放 解除诅咒；
否则对自己释放 解除诅咒
起死回生 与 治疗之触 进行link
野性印记 加buff宏 可以顺便加荆棘术
[quote]#show tooltip
/castsequence [target=target,help,nodead] reset=8/target 野性印记,荆棘术
/castsequence [target=player] resest=8/target 野性印记,荆棘术[/quote]
如果目标为存活的友方单位,对其依次使用 爪子和荆棘术, [顺序重置仅当目标切换或者8秒没有点击此宏]
否则 目标指定为自己，依次使用爪子和荆棘术, [顺序重置仅当目标切换或者8秒没有点击此宏]
野性赐福 未处理
驱毒术 驱毒宏 先放驱毒术后用消毒术
[quote]#show tooltip
/castsequence [target=target,help,nodead] reset=3/target 驱毒术,消毒术,消毒术,消毒术,消毒术
/castsequence [target=player] resest=3/target 驱毒术,消毒术,消毒术,消毒术,消毒术[/quote]
如果目标为存活的友方单位,对其依次使用 驱毒术和消毒术*4, [顺序重置仅当目标切换或者3秒没有点击此宏]
否则 目标指定为自己，依次使用 驱毒术和消毒术*4, [顺序重置仅当目标切换或者3秒没有点击此宏]
自然迅捷 顺加/顺吹宏
[quote]#showtooltip
/stopcasting
/cast [target=target,help,nodead] 治疗之触
/cast [target=target,harm,nodead] 旋风
/cast [target=player] 治疗之触
/stopcasting
/cast 自然迅捷[/quote]
点宏第一次打断当前施法并实用自然迅捷
猛击宏第二次根据目标属性使用治疗之触/旋风
[quote]#showtooltip
/stopcasting
/cast 自然迅捷
/cast [target=target,help,nodead] 治疗之触
/cast [target=target,harm,nodead] 旋风
/cast [target=player] 治疗之触
/stopcasting[/quote]
点宏第一次直接实现瞬加/瞬吹效果
这2个宏理论上OK,未测试。(从小到大一直野性…没出过那个自然迅捷)
[size=120%][color=skyblue]平衡 技能[/color][/size]
休眠 未处理
传送月光林地 未处理
安抚动物 未处理
愤怒 可加入协助
[quote]#showtooltip
/cast [target=target,nodead][target=targettarget,nodead] 愤怒[/quote]
可以协助MT 或者其他队员进行攻击
旋风 对焦点目标施放宏
[quote]#showtooltip
/cast [mod:alt,target=focus,nohelp,exists][target=target,nohelp,exists][target=focus,nohelp,exists] 旋风[/quote]
按住alt时，对焦点使用旋风
此外如果目标为存活的敌人,对其使用旋风
没有目标或者目标为右方时,对焦点使用旋风
有Alt焦点〉目标为敌人〉没有alt焦点
月火术,星火书 同愤怒 可协助
树皮术 与 野性部分技能 进行 link
激活 优化宏
[quote]#showtooltip
/cast [target=target,help,nodead][target=player] 激活[/quote]
目标为友方时,对其使用激活,此外对自己用
精灵之火 可协助,可焦点 未处理
纠缠根须 对焦点目标施放宏
[quote]#showtooltip
/cast [mod:alt,target=focus,nohelp,exists][target=target,nohelp,exists][target=focus,nohelp,exists] 纠缠根须[/quote]
按住alt时，对焦点使用纠缠根须；
此外如果目标为存活的敌人,对其使用纠缠根须
没有目标或者目标为友方时,对焦点使用纠缠根须
有Alt焦点〉目标为敌人〉没有alt焦点
自然之握 未处理
[size=120%][color=skyblue]野性 技能[/color][/size]
解除限制移动宏
[quote]/usesequence reset=0.5 ,联盟徽章
/cast [stance:1]!巨熊形态(变形);[stance:2]!水栖形态(变形);[nostance][stance:3]!猎豹形态(变形);[stance:4]!旅行形态(变形);[stance:5]!飞行形态(变形)[/quote]
抽筋宏,常规第一次使用解除限制或人形切旅行
0.5秒内连点使用 徽章 (调整reset=0.3~1 来合适使用者的手速)
常规变形宏
[quote]#showtooltip
/cancelform
/cast [outdoors,nocombat,flyable] 迅捷飞行形态
/cast [swimming] 水栖形态
/cast [outdoors] 旅行形态
/cast [indoors] 猎豹形态[/quote]
低吼 嘲讽宏
[quote]#showtooltip
/cast [target=mouseover,exists,nohelp,nodead][target=target,nohelp,nodead][target=focus,nohelp,nodead] 低吼 [/quote]
鼠标位置>当前目标>焦点
巨熊形态 和 猎豹形态 变身宏
[quote]#showtooltip
/cancelform
/cast 巨熊形态[/quote]
反应快,可以实现常规技能的所有功能
巨熊形态 和 猎豹形态 解除移动宏
[quote]#showtooltip
/cast !巨熊形态[/quote]
优点稳定,任何情况不出人形
毁灭 和 撕碎 宏
[quote]#showtooltip
/cast [stance:3,stealth] 毁灭;
[stance:3,nostealth] 撕碎 [/quote]
潜行放 毁灭,否则 撕碎
突袭 和 斜掠
[quote]#showtooltip
/cast [stance:3,stealth] 突袭;
[stance:3,nostealth] 斜掠[/quote]
潜行放 突袭,否则 斜掠
猛虎之怒 PVE 输出宏
[quote]#showtooltip
/castsequence reset=29.7 猛虎之怒,狂暴[/quote]
猛虎之怒优先用,其CD情况下使用狂暴
生存本能 防御类宏
[quote]#showtooltip
/cast [nostance:1/3] 巨熊形态
/castsequence reset=59.7 树皮术,生存本能
/cast [target=player] 生命之血[/quote]
非动物形态,变狗熊。树皮优先用,其CD情况下用生存本能，同时对自己 使用生命之血,我是草药D..
野性冲锋
[quote]#showtooltip
/cast [mod:alt,target=focus,nohelp,exists][target=target,nohelp,nodead,exists][target=focus,nohelp,nodead,exists] 野性冲锋[/quote]
加注 熊 / 猫 方可使用
精灵之火
[quote]#showtooltip
/cast [stance:1/3] 精灵之火(野性); 精灵之火
猫和熊使用野性火,其他形态普通火[/quote]
[color=teal]野性技能由于是近战射程,并且为常用主攻技能 所以并没有太多的想法来处理,有好的建议将某些技能整合优化可以跟贴回复,附上想法和所需应付的情况
部分平衡和回复技能也未处理,主要优化的价值自我感觉不大…[/color]
[color=darkred]文中由于排版问题可能会出显 半角/全角符号不同一，个别空格也可能无法正常显示出来,技能名称，物品名称错误 导致宏不能正常运行时,请阅读楼上有关语法的介绍。[/color]
[size=130%][color=skyblue]Part.D 更新部分 [/color][/size]
[color=green][b]11.17 关于文中宏格式的说明 [/b][/color]
我使用的格式主要是
[quote]#showtooltip
/cancelform
/cast [outdoors,nocombat,flyable] 迅捷飞行形态;
[swimming] 水栖形态;
[outdoors] 旅行形态;
[indoors] 猎豹形态[/quote]
这类格式好处内含if else逻辑,对于后面命令的[options]可以描述稍微松散些
并且便于查看 然后也有缺点 ; 遗失 空格 造成不能使用 99%的复制粘贴不能使用
通过打散可以换成
[quote]#showtooltip
/cancelform
/cast [outdoors,nocombat,flyable] 迅捷飞行形态
/cast [swimming] 水栖形态
/cast [outdoors] 旅行形态 <---会在可以飞行的情况下,尝试循环使用下,会有错误提示但不影响使用
/cast [indoors] 猎豹形态[/quote]
可以注意到所需的[options]需要比原来描述更详尽一点.
对于这种整个宏都是对于一个技能描述的
[quote]#showtooltip
/cast [target=mouseover,exists,nohelp,nodead] 低吼;
[target=target,nohelp,nodead] 低吼;
[target=focus,nohelp,nodead] 低吼 [/quote]
我将其转换为另外一个格式以便大家复制粘贴使用
[quote]#showtooltip
/cast [target=mouseover,exists,nohelp,nodead][target=target,nohelp,nodead][target=focus,nohelp,nodead] 低吼 [/quote]
这个格式的宏可以直接复制粘贴使用
由于这个格式 我刚刚学会,对于有2个不同技能还不清楚 怎么编写,请等待新的更新
[color=green][b]11.18 关于[options] [/b][/color]
/equip [options] itemname 可以使用 已实测
可以对于不同技能的使用前,换入各种不同的武器
HEAL/DPS技能使用前 换上高法伤武器
控制形技能使用前 换上高命中武器
动物形态 换上野性的武器
具体为在技能使用前第一行加入 /equip [stance:X] item
并且可以根据不同形态 更换不同的武器
/use [options] itemname
/s [options] %s
/cancelform [options]
这3个 理论上也可以 加入 [options] 进行判断 未测试
[color=green][b]12.1 关于宏变身的对比 [/b][/color]
感谢51L指出的问题
内容整合到了,原文中
并且添加了一个,解除限制移移动和徽章的整合宏
[color=green][b]12.1 添加了抽筋宏,喊话宏[/b][/color]
详见原文
[color=green][b]topmarco/runmarco [option]的使用[/b][/color]
通过条件判断,运行/停止宏的运行
[quote]#showtooltip
/cast [target=target,nocombat,dead][target=mouseover,nocambat.dead,exists] 起死回生; [target=target,help,nochanneling][target=targettarget,help,nochanneling][target=player,nochanneling] 治疗之触
/stopmacro [combat][target=none][target,nodead]
/y rise my solider[/quote]
通过个别情况的判断,后半段将不会运行,即不喊话
255字符怨念阿 ...
rise my solider，rise and fight one more
[color=green][b]12.22 添加了左右键 判断[/b][/color]
适合于 鼠标流,键盘流无效 左右键点击可出现不同效果
[quote]#showtooltip
/cast [button:1,target=target,help][button:1,target=player] 驱毒术;[button:2,target=target,help][button:2,target=player] 解除诅咒[/quote]
button:1 = 左键 button:2 = 右键
大多数一键解Debuff/grid插件都会的功能,此为No插件,宏的实现办法
改动
NGACN
劣化美.腹黑控.加害妄想症
用PowerAuras重顯AM 0/1
好运0/1
|
发表回复
发表新贴